Programming Taskbook


E-mail:

Пароль:

Регистрация пользователя   Восстановление пароля

 

ЮФУ SMBU

Электронный задачник по программированию

©  М. Э. Абрамян (Южный федеральный университет, Университет МГУ-ППИ в Шэньчжэне), 1998–2024

 

Решения | PascalABC.NET | Динамические структуры

PrevNext


Выполнение заданий на обработку динамических структур данных

Данная страница содержит подробное описание процесса решения типового задания на обработку динамических структур данных, а также примеры решения заданий на добавление элемента к динамической структуре, удаление элемента из динамической структуры, на обработку двусвязных и циклических динамических структур.

В отличие от описания, приведенного в разделе «Pascal | Динамические структуры», в котором для реализации динамических структур использовались записи и указатели, здесь рассматриваются группы заданий, в которых динамические структуры реализуются с помощью класса Node.

Анализ существующей динамической структуры: ObjDyn2

В заданиях группы ObjDyn мы встречаемся с двумя новыми видами данных: это объекты-узлы типа Node, а также динамические структуры, реализованные в виде цепочек связанных друг с другом объектов-узлов. Класс Node не входит в стандартную библиотеку PascalABC.NET; он определен в задачнике Programming Taskbook, а точнее, в модуле PT4.

Особенности, связанные с использованием новых типов данных, рассмотрим на примере задания ObjDyn2.

ObjDyn2°. Дан объект A1 типа Node. Этот объект связан своим свойством Next со следующим объектом типа Node, он, в свою очередь, — со следующим, и так далее до объекта со свойством Next, равным nil (таким образом, возникает цепочка связанных объектов). Вывести значения свойств Data для всех элементов цепочки, длину цепочки (т. е. число ее элементов) и ссылку на ее последний элемент.

Создание программы-заготовки и знакомство с заданием

Напомним, что программу-заготовку для решения задания можно создать с помощью модуля PT4Load. Приведем текст созданной заготовки (здесь и далее мы не будем указывать начальную директиву uses PT4):

begin
  Task('ObjDyn2');
end.

После запуска программы на экране появится окно задачника. На рисунке приводится вид окна в режиме с динамической компоновкой, появившемся в версии 4.11 задачника.

Это окно содержит в качестве исходных и результирующих данных новые элементы: динамические структуры и объектные ссылки на них.

Начнем с описания того, как отображается на экране динамическая структура. Для ее вывода используются две экранные строки; в первой строке отображаются имена объектов, связанных с данной структурой, а во второй — содержимое элементов этой структуры, т. е. значения их свойств Data и способ связи между ними. Вся информация о динамической структуре отображается бирюзовым цветом (подобно информации об элементах файлов). Рассмотрим в качестве примера динамическую структуру, указанную на рисунке:

 A1
 61 - 17 - 10 - 43 - 10 >nil

Этот текст означает, что структура состоит из 5 элементов, причем ее первый элемент имеет свойство Data, равное 61, и связан с помощью своего свойства Next со вторым элементом, свойство Data которого равно 17, и так далее до последнего, пятого элемента, свойство Data которого равно 10, а свойство Next равно nil, что является признаком завершения структуры. Таким образом, текст, описывающий данную динамическую структуру, является упрощенным вариантом следующей схемы:

Так как эта структура указана в разделе исходных данных, следовательно, после инициализации задания она уже существует и размещается в некоторой области динамической памяти (подобно тому, как исходные файлы после инициализации задания размещаются в каталоге учащегося). Как получить доступ к существующей динамической структуре? Здесь также уместна аналогия с файлами. Для доступа к внешнему файлу необходимо знать его имя, и в любом задании на обработку файлов имена исходных файлов входят в набор исходных данных. Для доступа к цепочке узлов, размещенной в динамической памяти, достаточно иметь переменную типа Node, ссылающуюся на некоторый узел этой цепочки — объект класса Node (напомним, что в языке PascalABC.NET любая переменная классового типа содержит ссылку, т. е. адрес той области динамической памяти, в которой размещается объект данного класса). Поэтому в любом задании на обработку динамических структур в набор исходных данных входят данные типа Node, которые содержат ссылки на элементы исходных структур, созданных задачником.

Из текста, описывающего динамическую структуру, видно, что на ее первый элемент ссылается объект с именем A1, который также содержится в наборе исходных данных. Описание этого объекта имеет вид

A1 = Node

Здесь текст «A1 =» является комментарием и выделяется, как обычный комментарий, черным цветом, а текст «Node», выделенный синим цветом, означает, что этот элемент исходных данных является объектом типа Node, который надо ввести в программу с помощью функции ReadNode.

Итак, слово «Node» в разделе исходных или результирующих данных означает, что соответствующий элемент данных является объектом-узлом (определить, каким именно элементом динамической структуры является объект-узел, можно по экранной информации об этой динамической структуре). Если же элемент данных типа Node не связан ни с каким узлом (т. е. содержит нулевую ссылку), то для него используется обозначение «nil».

Создав (или преобразовав) динамическую структуру, программа учащегося должна передать задачнику некоторый объект-узел, связанный с этой структурой (используя процедуру Write или Print). Получив этот объект, задачник сможет проверить правильность созданной структуры.

Приступаем к решению

Вернемся к заданию ObjDyn2. В нем не требуется ни создавать, ни преобразовывать исходную структуру данных; ее необходимо лишь проанализировать, а именно, определить значения всех ее элементов, подсчитать количество элементов и, кроме того, вывести ссылку на последний элемент этой структуры.

Приведем вначале неполное решение задачи, выводящее все необходимые данные, кроме ссылки на последний элемент:

begin
  Task('ObjDyn2');
  var a1 := ReadNode;
  var n := 0;
  while a1 <> nil do
  begin
    Print(a1.Data);
    n += 1;
    a1 := a1.Next;
  end;
  Print(n);
end.

После запуска программы можно убедиться, что все числовые результирующие данные определены правильно, однако из-за того, что не выведена ссылка на последний элемент, решение признано ошибочным с диагностикой «Выведены не все результирующие данные».

Добавим в конец программы оператор

Print(a1);

После запуска нового варианта программы все требуемые данные будут выведены, однако результирующее значение ссылки будет равно nil. Это связано с тем, что после завершения цикла while в переменной a1 содержится нулевая ссылка, а не ссылка на последний элемент динамической структуры.

Правильное решение

Для того чтобы получить правильное решение, опишем вспомогательную переменную a2, в которой будем сохранять ссылку на объект, предшествующий объекту a1. После завершения цикла while в этой переменной будет содержаться ссылка на последний элемент динамической структуры:

begin
  Task('ObjDyn2');
  var a1 := ReadNode;
  var a2: Node;
  var n := 0;
  while a1 <> nil do
  begin
    Print(a1.Data);
    n += 1;
    a2 := a1;
    a1 := a1.Next;
  end;
  Print(n, a2);
end.

Проверив программу на трех тестовых наборах, мы получим сообщение «Задание выполнено!».


Добавление элемента к динамической структуре: ObjDyn3

Рассмотрим задание ObjDyn3, связанное с добавлением элемента к динамической структуре-стеку.

ObjDyn3°. Дано число D и вершина A1 непустого стека. Добавить элемент со значением D в стек и вывести ссылку A2 на новую вершину стека.

Знакомство с заданием

При ознакомительном запуске этого задания мы обнаружим новое обозначение в тексте, описывающем динамическую структуру, а именно точки, обрамляющие первый элемент результирующего стека (на рисунке так выделен элемент 93).

Точки обозначают элементы динамической структуры, которые должны быть созданы программой учащегося (в отличие от тех элементов, которые создаются самим задачником при инициализации задания).

Приступаем к решению

Что произойдет, если динамическая структура будет создана с ошибками? Для того чтобы это выяснить, вернем в программе, решающей задание ObjDyn3, ссылку на прежнюю вершину стека, не добавляя к ней новый элемент:

begin
  Task('ObjDyn3');
  var d := ReadInteger;
  var a1 := ReadNode;
  Print(a1);
end.

В результате, если исходный стек содержал, к примеру, четыре элемента со значениями 12, 24, 74 и 49, полученный стек будет отображен на экране следующим образом:

 A2
(12)-(24)-(74)-(49)>nil

Скобки вокруг каждого элемента означают, что эти элементы созданы самим задачником, но располагаются не на тех позициях, на которых они должны находиться при правильном решении. Действительно, тот элемент, который в решении является первым, должен (после добавления нового элемента) оказаться вторым и т. д. Итак, наличие скобок в тексте результирующей динамической структуры означает, что ее элементы располагаются не в том порядке, который требуется.

Правильное решение

Для получения правильного решения задания ObjDyn3 необходимо создать новый элемент, вызвав для него конструктор класса Node. Параметры конструктора надо указать таким образом, чтобы свойство Data созданного элемента получило нужное числовое значение, а свойство Next обеспечило связь созданного элемента с текущей вершиной стека. В результате созданный объект будет добавлен в стек и станет его новой вершиной, ссылку на которую и следует вывести:

begin
  Task('ObjDyn3');
  var d := ReadInteger;
  var a1 := ReadNode;
  var a2 := new Node(d, a1);
  Print(a2);
end.

Проверив программу на пяти тестовых наборах, мы получим сообщение «Задание выполнено!».

Примечание 1. Решение можно записать в виде единственного оператора, если сразу передать исходные данные конструктору и вывести тот объект, который этот конструктор возвратит:

begin
  Task('ObjDyn3');
  Print(new Node(GetInteger, GetNode));
end.

Удаление элемента из динамической структуры: ObjDyn5

Рассмотрим задание ObjDyn5, связанное с удалением элемента из динамической структуры.

ObjDyn5°. Дана вершина A1 непустого стека. Извлечь из стека первый (верхний) элемент и вывести его значение D, а также ссылку A2 на новую вершину стека. Если после извлечения элемента стек окажется пустым, то положить A2 = nil. После извлечения элемента из стека освободить ресурсы, используемые этим элементом, вызвав его метод Dispose.

Знакомство с заданием

Особенность заданий на удаление элементов из динамических структур заключается в том, что при их выполнении необходимо не только «отсоединять» удаляемые элементы от исходных структур, но и освобождать выделенные для них ресурсы, вызывая специальный метод Dispose, определенный в классе Node.

Все объекты стандартной библиотеки PascalABC.NET, требующие для своей работы неуправляемые ресурсы, снабжаются особым методом очистки Dispose, вызов которого освобождает ресурсы, выделенные для данного объекта (для некоторых групп объектов, например, для файлов, метод очистки имеет имя Close). Хотя для большинства классов, снабженных методом очистки, предусмотрен автоматический вызов этого метода при разрушении объекта, желательно вызывать метод очистки явно, как только программа завершит работу с данным объектом. В частности, следует явным образом закрывать все открытые файлы, что мы и делали в примерах выполнения учебных заданий на обработку файлов.

Аналогичная ситуация имеет место и для класса Node. Этот класс также использует ресурсы, поэтому в нем предусмотрен метод очистки с именем Dispose, предназначенный для их освобождения. Сам задачник «следит» за тем, чтобы данный метод был вызван для тех объектов-узлов, которые следует удалить из исходной динамической структуры. Текст, связанный с подобными объектами-узлами, выделяется на экране бирюзовым цветом большей яркости, чем цвет обычных элементов динамической структуры; это служит дополнительным напоминанием о необходимости вызова для данных объектов метода Dispose (на рисунке таким способом выделен элемент 37).

Приступаем к решению

Вначале приведем неправильный вариант решения, в котором не освобождается память, занимаемая удаленным из стека элементом:

begin
  Task('ObjDyn5');
  var a1 := ReadNode;
  Print(a1.Data, a1.Next);
end.

Хотя все результирующие данные будут совпадать с контрольными (т. е. текст на вкладках «Полученные результаты» и «Пример верного решения» будет одинаковым), на информационной панели появится сообщение об ошибке «Не вызван метод Dispose для объекта типа Node», а в разделе исходных данных будет выделен красным цветом тот элемент, который требовалось удалить.

Правильное решение

Для получения правильного решения достаточно добавить в конец программы вызов метода Dispose для объекта a1, удаленного из стека:

  a1.Dispose;

Проверив исправленную программу на пяти тестовых наборах, мы получим сообщение «Задание выполнено!».

Примечание 2. Начиная с версии 4.15, в вариант задачника для среды PascalABC.NET включена также группа GCDyn, отличающаяся от группы ObjDyn тем, что при выполнении заданий группы GCDyn на удаление узлов из динамических структур (эти задания имеют номера 5–7, 12–13, 18–20, 27–28, 41–43, 65, 72–73, 80) не требуется освобождать ресурсы, связанные с удаляемыми узлами (предполагается, что эти действия автоматически выполняются специальным сборщиком мусора — Garbage Collector, GC). Таким образом, при использовании группы GCDyn решение задания GCDyn5 (аналогичного заданию ObjDyn5) будет считаться правильным и без вызова метода Dispose.


Двусвязные динамические структуры: ObjDyn30

Особенности работы с двусвязными динамическими структурами рассмотрим на примере задания ObjDyn30.

ObjDyn30°. Дана ссылка A1 на начало непустой цепочки элементов-объектов типа Node, связанных между собой с помощью своих свойств Next. Используя свойства Prev данных объектов, преобразовать исходную (односвязную) цепочку в двусвязную, в которой каждый элемент связан не только с последующим элементом (с помощью свойства Next), но и с предыдущим (с помощью свойства Prev). Свойство Prev первого элемента положить равным nil. Вывести ссылку A2 на последний элемент преобразованной цепочки.

Знакомство с заданием

Запустив программу-заготовку, созданную для этого задания, мы увидим в области исходных данных информацию об «обычной» односвязной структуре, подобной рассмотренным в предыдущих заданиях, например:

 A1
 35 - 11 - 36 - 39 - 56 >nil

Динамическая структура, приведенная в разделе результатов, будет иметь две особенности: во-первых, ее элементы связаны символом «=», а во-вторых, перед первым элементом присутствует текст «nil<»:

                         A2
nil< 35 = 11 = 36 = 39 = 56 >nil

Это означает, что результирующая структура является двусвязной, т. е. каждый ее элемент связан не только с последующим элементом (с помощью свойства Next, как в односвязной структуре), но и с предыдущим элементом (с помощью нового свойства Prev), а свойство Prev первого элемента имеет значение nil:

Решение задачи

Для преобразования исходной односвязной структуры в двусвязную необходимо задать правильные значения для свойств Prev всех элементов структуры, перебирая в цикле пары соседних элементов:

begin
  Task('ObjDyn30');
  var a1 := ReadNode;
  var a2: Node := nil;
  while a1 <> nil do
  begin
    a1.Prev := a2;
    a2 := a1;
    a1 := a1.Next;
  end;
  Print(a2);
end.

Проверив программу на пяти тестовых наборах, мы получим сообщение «Задание выполнено!».


Циклические динамические структуры: ObjDyn55

Динамическая структура называется циклической, если она замкнута в «кольцо», т. е. ее последний элемент связан свойством Next с первым (в случае двусвязной структуры требуется также, чтобы ее первый элемент был связан свойством Prev с последним элементом). Простейшим заданием на циклические структуры является ObjDyn55.

ObjDyn55°. Дан первый элемент A1 непустого двусвязного списка. Преобразовать список в циклический, записав в свойство Next последнего элемента списка ссылку на его первый элемент, а в свойство Prev первого элемента — ссылку на последний элемент списка. Вывести ссылку на элемент, который был последним элементом исходного списка.

Знакомство с заданием

Запустив программу-заготовку для этого задания, мы увидим на экране изображения двух динамических структур, которые будут выглядеть следующим образом (первая структура — исходный двусвязный список, вторая структура — результирующий циклический двусвязный список):

     A1
nil< 19 = 94 = 51 = 41 = 55 >nil

                         A2
<< = 19 = 94 = 51 = 41 = 55 = >>

Обозначения «<< =» и «= >>» позволяют отличить циклический список от обычного (напомним, что у обычного двусвязного списка свойство Prev первого элемента и свойство Next последнего элемента равны nil). Таким образом, экранный текст, описывающий циклический двусвязный список, является упрощенным вариантом следующей схемы:

Решение задачи

Для решения задания ObjDyn55 достаточно найти последний элемент исходного списка и связать его с первым элементом:

begin
  Task('ObjDyn55');
  var a1 := ReadNode;
  var a2 := a1;
  while a2.Next <> nil do
    a2 := a2.Next;
  a2.Next := a1;
  Print(a2);
end.

В этом варианте решения мы «забыли» о том, что надо связать не только последний элемент с первым, но и первый с последним (поскольку наш список — двусвязный). Поэтому решение будет считаться ошибочным, причем в области результатов после последнего элемента будет изображен символ одинарной, а не двойной связи, например:

               A2
nil< 38 = 24 = 91 - >>

Для получения правильного решения достаточно добавить в программу перед процедурой вывода Print следующий оператор:

  a1.Prev := a2;

Проверив исправленную программу на трех тестовых наборах, мы получим сообщение «Задание выполнено!».


PrevNext

 

Рейтинг@Mail.ru

Разработка сайта:
М. Э. Абрамян, В. Н. Брагилевский

Последнее обновление:
01.01.2024